module Main where

import Data.List (isPrefixOf)
import Control.Category ((>>>))
import Control.Monad (forM_, when)
import Control.Monad.Identity (Identity)
import Data.Aeson (ToJSON (..), Value (..), encode)
import qualified Data.ByteString.Lazy.Char8 as BL
import qualified Data.Text.IO as TextIO
import Data.Typeable
import GHC.IO.Exception (ExitCode (ExitFailure, ExitSuccess))
import Language.Fiddle.Ast
import Language.Fiddle.Compiler
import Language.Fiddle.Compiler.Backend
import Language.Fiddle.Compiler.Backend.C
import Language.Fiddle.Compiler.ConsistencyCheck
import Language.Fiddle.Compiler.Expansion
import Language.Fiddle.Compiler.ImportResolution
import Language.Fiddle.Compiler.Qualification
import Language.Fiddle.Compiler.Stage0
import Language.Fiddle.GenericTree
import Language.Fiddle.Types (Commented (unCommented), SourceSpan)
import Options.Applicative
import Options.Applicative.Types (ParserHelp (..))
import qualified System.Environment as System
import System.Exit (exitWith)
import System.IO (hPutStrLn, stderr)

newtype IntermediateAst = IntermediateAst (GenericSyntaxTree Identity (Maybe Value))
  deriving (Typeable)

-- | The total compilation pipeline.
compilationPipeline ::
  ( FilePath ->
    IO
      ( [Diagnostic],
        [Artifact],
        Maybe
          ( FiddleUnit Parsed Identity (Commented SourceSpan)
          )
      )
  ) ->
  ( FiddleUnit Parsed Identity (Commented SourceSpan) ->
    IO
      ( [Diagnostic],
        [Artifact],
        Maybe
          (FiddleUnit Checked Identity (Commented SourceSpan))
      )
  ) ->
  CompilationPhase Parsed Checked
compilationPipeline parse compile =
  (dumpPhase "parsed" >>> importResolutionPhase parse compile)
    >>> (dumpPhase "imports-resolved" >>> expansionPhase)
    >>> (dumpPhase "expanded" >>> qualificationPhase)
    >>> (dumpPhase "qualified" >>> consistencyCheckPhase)
    >>> dumpPhase "checked"

-- | Compilation phase that just emits an ast artifact.
dumpPhase ::
  forall stage.
  ( Typeable stage,
    Typeable (StageAnnotation stage),
    ToGenericSyntaxTree (FiddleUnit stage),
    StageAnnotation stage ~ Commented SourceSpan
  ) =>
  String ->
  CompilationPhase stage stage
dumpPhase stageName =
  CompilationPhase
    ( switch
        ( long ("dump-" ++ stageName)
            <> help
              ( "Dump the "
                  ++ stageName
                  ++ " intermediate ast as parseable JSON."
              )
        )
    )
    (\_ _ -> return ([], Just ()))
    ( \enable () ast -> do
        when enable $
          emitArtifact $
            Artifact $
              IntermediateAst (toGenericSyntaxTree (fmap (Just . toJSON) ast))
        return ast
    )

-- | Global flags for the compiler.
data GlobalFlags = GlobalFlags
  { flagsInputFile :: String,
    flagsDiagnosticFormat :: DiagnosticFormat,
    flagsBackend :: String
  }

-- | Parse global flags from command line arguments.
parseGlobalFlags :: Parser GlobalFlags
parseGlobalFlags =
  GlobalFlags
    <$> argument str (metavar "INPUT" <> help "Input file")
    <*> ( (\b -> if b then jsonDiagnosticFormat else coloredFormat)
            <$> switch
              ( long "diagnostics-as-json"
                  <> help "Dump diagnostics in JSON format."
              )
        )
    <*> strOption
      ( long "language"
          <> short 'L'
          <> help "The output language"
          <> metavar "LANGUAGE"
      )

-- | Parse the input file into the initial AST stages.
doParse :: String -> IO ([Diagnostic], [Artifact], Maybe (TreeType FiddleUnit Parsed))
doParse filePath = do
  text <- TextIO.readFile filePath
  return $ compile_ $ toStage0 filePath text >>= toStage1

-- | Run the compilation pipeline with the given command-line arguments and AST.
runCompilationPipeline ::
  [String] ->
  TreeType FiddleUnit Parsed ->
  IO ([Diagnostic], [Artifact], Maybe (TreeType FiddleUnit Checked))
runCompilationPipeline argv tree =
  case fromArgs argv of
    Success (_, pipelineAction, _) -> pipelineAction tree
    _ ->
      return
        ( [Diagnostic Error "Internal parsing failure (this is a bug)." (unCommented $ annot tree)],
          [],
          Nothing
        )

-- | Parse command-line arguments into global flags and a compilation action.
fromArgs ::
  [String] ->
  ParserResult
    ( GlobalFlags,
      TreeType FiddleUnit Parsed ->
      IO ([Diagnostic], [Artifact], Maybe (TreeType FiddleUnit Checked)),
      FiddleUnit Checked Identity (Commented SourceSpan) -> IO TranspileResult
    )
fromArgs argv =
  case selectBackend argv of
    Just backend -> do
      execParserPure
        defaultPrefs
        (parserInfo backend)
        argv
    Nothing ->
      Failure $
        parserFailure
          defaultPrefs
          (parserInfo nullBackend)
          (ErrorMsg "Unknown backend")
          mempty
  where
    selectBackend :: [String] -> Maybe Backend
    selectBackend argv = selectBackendEq argv <|> selectBackendSpace argv

    selectBackendEq argv =
       case filter ("--language="`isPrefixOf`) argv of
          [backend] -> case break (=='=') backend of
             (_, '=' : s) -> selectBackendFromString s
             _ -> Nothing
          _ -> Nothing

    selectBackendSpace argv =
      case break (\s -> s == "--language" || "-L" `isPrefixOf` s) argv of
        (_, "--language" : s : _) -> selectBackendFromString s
        (_, "-L" : s : _) -> selectBackendFromString s
        (_, ('-' : 'L' : s) : _) -> selectBackendFromString s
        _ -> Nothing

    selectBackendFromString "c" = Just cBackend
    selectBackendFromString "null" = Just nullBackend
    selectBackendFromString _ = Nothing
         

    parserInfo backend =
      info
        ( (,,)
            <$> parseGlobalFlags
            <*> execCompilationPipelineWithCmdline
              (compilationPipeline doParse (runCompilationPipeline argv))
            <*> backendToParserFunction backend
              <**> helper
        )
        ( fullDesc
            <> progDesc "Compile Fiddle Files"
            <> header "fiddlec - A compiler for Fiddle files"
        )

main :: IO ()
main = do
  argv <- System.getArgs
  (globalFlags, compilationAction, backendAction) <- parseCommandLineArgs argv
  let filePath = flagsInputFile globalFlags

  maybeParsedAst <- parseInputFile filePath
  case maybeParsedAst of
    (priorDiags, _, Just ast) -> do
      ((priorDiags ++) -> diags, artifacts, ma) <- compilationAction ast
      exitCode <- processCompilationResult artifacts ma backendAction
      printDiagnostics (flagsDiagnosticFormat globalFlags) diags
      exitWith exitCode
    (diags, _, _) ->
      handleParsingFailure (flagsDiagnosticFormat globalFlags) diags

-- | Parse command-line arguments, exiting on failure.
parseCommandLineArgs ::
  [String] ->
  IO
    ( GlobalFlags,
      TreeType FiddleUnit Parsed ->
      IO ([Diagnostic], [Artifact], Maybe (TreeType FiddleUnit Checked)),
      FiddleUnit Checked Identity (Commented SourceSpan) -> IO TranspileResult
    )
parseCommandLineArgs argv = handleParseResult (fromArgs argv)

-- | Parse the input file into the initial AST.
parseInputFile :: String -> IO ([Diagnostic], [Artifact], Maybe (TreeType FiddleUnit Parsed))
parseInputFile filePath = do
  text <- TextIO.readFile filePath
  return $ compile_ $ toStage0 filePath text >>= toStage1

-- | Process the compilation result, printing the output and returning the exit code.
processCompilationResult ::
  [Artifact] -> Maybe (TreeType FiddleUnit Checked) -> 
   (TreeType FiddleUnit Checked -> IO TranspileResult)
  -> IO ExitCode
processCompilationResult artifacts ma backendFunction = do
  forM_ artifacts $ \case
    Artifact (cast -> (Just (IntermediateAst ast))) ->
      putStrLn $
        BL.unpack $
          encode $
            alterGenericSyntaxTree cleanupIdentifiers ast
    Artifact _ -> return ()

  case ma of
    Just ast -> do
      processTranspileResult =<< backendFunction ast
      return ExitSuccess
    Nothing -> do
      return (ExitFailure 1)

-- | Handle parsing failures by printing diagnostics and exiting with an error code.
handleParsingFailure :: DiagnosticFormat -> [Diagnostic] -> IO ()
handleParsingFailure fmt diags = do
  printDiagnostics fmt diags
  exitWith (ExitFailure 1)

-- | Clean up identifiers in the generic syntax tree for serialization.
cleanupIdentifiers :: GenericSyntaxTree Identity a -> Maybe (GenericSyntaxTree Identity a)
cleanupIdentifiers (SyntaxTreeObject _ _ _ tr)
  | Just (Identifier n _) <- castT tr =
      Just $ SyntaxTreeValue (String n)
  where
    castT :: (Typeable t, Typeable f, Typeable a, Typeable t') => t f a -> Maybe (t' f a)
    castT = cast
cleanupIdentifiers _ = Nothing