4 files changed, 144 insertions, 12 deletions
diff --git a/third-party/cmake/BuildLua.cmake b/third-party/cmake/BuildLua.cmake
index b24ef089de..1c5e2a186c 100644
--- a/third-party/cmake/BuildLua.cmake
+++ b/third-party/cmake/BuildLua.cmake
@@ -77,7 +77,7 @@ set(BUSTED ${DEPS_INSTALL_DIR}/bin/busted)
 set(BUSTED_LUA ${BUSTED}-lua)
 
 add_custom_command(OUTPUT ${BUSTED_LUA}
-  COMMAND sed -e 's/jit//g' < ${BUSTED} > ${BUSTED_LUA} && chmod +x ${BUSTED_LUA}
+  COMMAND sed -e 's/^exec/exec $$LUA_DEBUGGER/' -e 's/jit//g' < ${BUSTED} > ${BUSTED_LUA} && chmod +x ${BUSTED_LUA}
   DEPENDS lua)
 add_custom_target(busted-lua
   DEPENDS ${DEPS_INSTALL_DIR}/bin/busted-lua)
diff --git a/third-party/cmake/BuildLuarocks.cmake b/third-party/cmake/BuildLuarocks.cmake
index a6126af789..1662f89b24 100644
--- a/third-party/cmake/BuildLuarocks.cmake
+++ b/third-party/cmake/BuildLuarocks.cmake
@@ -89,25 +89,26 @@ list(APPEND THIRD_PARTY_DEPS luarocks)
 
 if(USE_BUNDLED_LUAJIT)
   add_dependencies(luarocks luajit)
+  if(MINGW AND CMAKE_CROSSCOMPILING)
+    add_dependencies(luarocks luajit_host)
+  endif()
 endif()
 
 # Each target depends on the previous module, this serializes all calls to
 # luarocks since it is unhappy to be called in parallel.
-add_custom_command(OUTPUT ${HOSTDEPS_LIB_DIR}/luarocks/rocks/lua-messagepack
+add_custom_command(OUTPUT ${HOSTDEPS_LIB_DIR}/luarocks/rocks/mpack
   COMMAND ${LUAROCKS_BINARY}
-  ARGS build lua-messagepack ${LUAROCKS_BUILDARGS}
+  ARGS build mpack ${LUAROCKS_BUILDARGS}
   DEPENDS luarocks)
-add_custom_target(lua-messagepack
-  DEPENDS ${HOSTDEPS_LIB_DIR}/luarocks/rocks/lua-messagepack)
-list(APPEND THIRD_PARTY_DEPS lua-messagepack)
+add_custom_target(mpack
+  DEPENDS ${HOSTDEPS_LIB_DIR}/luarocks/rocks/mpack)
+list(APPEND THIRD_PARTY_DEPS mpack)
 
 
-# Like before, depend on lua-messagepack to ensure serialization of install
-# commands
 add_custom_command(OUTPUT ${HOSTDEPS_LIB_DIR}/luarocks/rocks/lpeg
   COMMAND ${LUAROCKS_BINARY}
   ARGS build lpeg ${LUAROCKS_BUILDARGS}
-  DEPENDS lua-messagepack)
+  DEPENDS mpack)
 add_custom_target(lpeg
   DEPENDS ${HOSTDEPS_LIB_DIR}/luarocks/rocks/lpeg)
 
@@ -117,7 +118,7 @@ if(USE_BUNDLED_BUSTED)
   add_custom_command(OUTPUT ${HOSTDEPS_BIN_DIR}/busted
     COMMAND ${LUAROCKS_BINARY}
     ARGS build https://raw.githubusercontent.com/Olivine-Labs/busted/v2.0.rc11-0/busted-2.0.rc11-0.rockspec ${LUAROCKS_BUILDARGS}
-    DEPENDS luarocks)
+    DEPENDS lpeg)
   add_custom_target(busted
     DEPENDS ${HOSTDEPS_BIN_DIR}/busted)
 
@@ -128,10 +129,22 @@ if(USE_BUNDLED_BUSTED)
   add_custom_target(luacheck
     DEPENDS ${HOSTDEPS_BIN_DIR}/luacheck)
 
+  set(LUV_DEPS luacheck luv-static)
+  if(MINGW AND CMAKE_CROSSCOMPILING)
+    set(LUV_DEPS ${LUV_DEPS} libuv_host)
+  endif()
+  add_custom_command(OUTPUT ${HOSTDEPS_LIB_DIR}/luarocks/rocks/luv
+    COMMAND ${LUAROCKS_BINARY}
+    ARGS make ${LUAROCKS_BUILDARGS} LIBUV_DIR=${HOSTDEPS_INSTALL_DIR} CFLAGS='-O0 -g3 -fPIC'
+    WORKING_DIRECTORY ${DEPS_BUILD_DIR}/src/luv
+    DEPENDS ${LUV_DEPS})
+  add_custom_target(luv
+    DEPENDS ${HOSTDEPS_LIB_DIR}/luarocks/rocks/luv)
+
   add_custom_command(OUTPUT ${HOSTDEPS_LIB_DIR}/luarocks/rocks/nvim-client
     COMMAND ${LUAROCKS_BINARY}
-    ARGS build https://raw.githubusercontent.com/neovim/lua-client/0.0.1-14/nvim-client-0.0.1-14.rockspec ${LUAROCKS_BUILDARGS} LIBUV_DIR=${HOSTDEPS_INSTALL_DIR}
-    DEPENDS luacheck libuv)
+    ARGS build https://raw.githubusercontent.com/neovim/lua-client/0.0.1-24/nvim-client-0.0.1-24.rockspec ${LUAROCKS_BUILDARGS}
+    DEPENDS luv)
   add_custom_target(nvim-client
     DEPENDS ${HOSTDEPS_LIB_DIR}/luarocks/rocks/nvim-client)
 
diff --git a/third-party/cmake/BuildLuv.cmake b/third-party/cmake/BuildLuv.cmake
new file mode 100644
index 0000000000..3060590bce
--- /dev/null
+++ b/third-party/cmake/BuildLuv.cmake
@@ -0,0 +1,90 @@
+include(CMakeParseArguments)
+
+# BuildLuv(PATCH_COMMAND ... CONFIGURE_COMMAND ... BUILD_COMMAND ... INSTALL_COMMAND ...)
+# Reusable function to build luv, wraps ExternalProject_Add.
+# Failing to pass a command argument will result in no command being run
+function(BuildLuv)
+  cmake_parse_arguments(_luv
+    ""
+    ""
+    "PATCH_COMMAND;CONFIGURE_COMMAND;BUILD_COMMAND;INSTALL_COMMAND"
+    ${ARGN})
+
+  if(NOT _luv_CONFIGURE_COMMAND AND NOT _luv_BUILD_COMMAND
+       AND NOT _luv_INSTALL_COMMAND)
+    message(FATAL_ERROR "Must pass at least one of CONFIGURE_COMMAND, BUILD_COMMAND, INSTALL_COMMAND")
+  endif()
+
+  ExternalProject_Add(luv-static
+    PREFIX ${DEPS_BUILD_DIR}
+    URL ${LUV_URL}
+    DOWNLOAD_DIR ${DEPS_DOWNLOAD_DIR}/luv
+    DOWNLOAD_COMMAND ${CMAKE_COMMAND}
+      -DPREFIX=${DEPS_BUILD_DIR}
+      -DDOWNLOAD_DIR=${DEPS_DOWNLOAD_DIR}/luv
+      -DURL=${LUV_URL}
+      -DEXPECTED_SHA256=${LUV_SHA256}
+      -DTARGET=luv
+      -DUSE_EXISTING_SRC_DIR=${USE_EXISTING_SRC_DIR}
+      -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/DownloadAndExtractFile.cmake
+    PATCH_COMMAND "${_luv_PATCH_COMMAND}"
+    CONFIGURE_COMMAND "${_luv_CONFIGURE_COMMAND}"
+    BUILD_COMMAND "${_luv_BUILD_COMMAND}"
+    INSTALL_COMMAND "${_luv_INSTALL_COMMAND}")
+endfunction()
+
+set(LUV_SRC_DIR ${DEPS_BUILD_DIR}/src/luv)
+set(LUV_INCLUDE_FLAGS
+  "-I${DEPS_INSTALL_DIR}/include -I${DEPS_INSTALL_DIR}/include/luajit-2.0")
+
+set(LUV_PATCH_COMMAND
+  ${CMAKE_COMMAND} -DLUV_SRC_DIR=${LUV_SRC_DIR}
+  -P ${PROJECT_SOURCE_DIR}/cmake/PatchLuv.cmake)
+
+set(LUV_CONFIGURE_COMMAND_COMMON
+  ${CMAKE_COMMAND} ${LUV_SRC_DIR}
+  -DCMAKE_INSTALL_PREFIX=${DEPS_INSTALL_DIR}
+  -DLUA_BUILD_TYPE=System
+  -DWITH_SHARED_LIBUV=ON
+  -DBUILD_SHARED_LIBS=OFF
+  -DBUILD_MODULE=OFF)
+
+if(MINGW AND CMAKE_CROSSCOMPILING)
+  get_filename_component(TOOLCHAIN ${CMAKE_TOOLCHAIN_FILE} REALPATH)
+  set(LUV_CONFIGURE_COMMAND
+    ${LUV_CONFIGURE_COMMAND_COMMON}
+    # Pass toolchain
+    -DCMAKE_TOOLCHAIN_FILE=${TOOLCHAIN}
+    "-DCMAKE_C_FLAGS:STRING=${LUV_INCLUDE_FLAGS} -D_WIN32_WINNT=0x0600"
+    # Hack to avoid -rdynamic in Mingw
+    -DCMAKE_SHARED_LIBRARY_LINK_C_FLAGS="")
+elseif(MSVC)
+  set(LUV_CONFIGURE_COMMAND
+    ${LUV_CONFIGURE_COMMAND_COMMON}
+    -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+    # Same as Unix without fPIC
+    "-DCMAKE_C_FLAGS:STRING=${CMAKE_C_COMPILER_ARG1} ${LUV_INCLUDE_FLAGS}"
+    # Make sure we use the same generator, otherwise we may
+    # accidentaly end up using different MSVC runtimes
+    -DCMAKE_GENERATOR=${CMAKE_GENERATOR}
+    # Use static runtime
+    -DCMAKE_C_FLAGS_DEBUG="-MTd"
+    -DCMAKE_C_FLAGS_RELEASE="-MT")
+else()
+  set(LUV_CONFIGURE_COMMAND
+    ${LUV_CONFIGURE_COMMAND_COMMON}
+    -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+    "-DCMAKE_C_FLAGS:STRING=${CMAKE_C_COMPILER_ARG1} ${LUV_INCLUDE_FLAGS} -fPIC")
+endif()
+
+set(LUV_BUILD_COMMAND ${CMAKE_COMMAND} --build .)
+set(LUV_INSTALL_COMMAND ${CMAKE_COMMAND} --build . --target install)
+
+BuildLuv(PATCH_COMMAND ${LUV_PATCH_COMMAND}
+  CONFIGURE_COMMAND ${LUV_CONFIGURE_COMMAND}
+  BUILD_COMMAND ${LUV_BUILD_COMMAND}
+  INSTALL_COMMAND ${LUV_INSTALL_COMMAND})
+
+list(APPEND THIRD_PARTY_DEPS luv-static)
+add_dependencies(luv-static luajit)
+add_dependencies(luv-static libuv)
diff --git a/third-party/cmake/PatchLuv.cmake b/third-party/cmake/PatchLuv.cmake
new file mode 100644
index 0000000000..96595a2f30
--- /dev/null
+++ b/third-party/cmake/PatchLuv.cmake
@@ -0,0 +1,29 @@
+# replace luv default rockspec with the alternate one under the "rockspecs"
+# directory
+file(GLOB LUV_ROCKSPEC RELATIVE ${LUV_SRC_DIR} ${LUV_SRC_DIR}/*.rockspec)
+file(RENAME ${LUV_SRC_DIR}/rockspecs/${LUV_ROCKSPEC} ${LUV_SRC_DIR}/${LUV_ROCKSPEC})
+
+# Some versions of mingw are missing defines required by luv dns module, add
+# them now
+set(LUV_SRC_DNS_C_DEFS
+"#ifndef AI_NUMERICSERV
+# define AI_NUMERICSERV 0x0008
+#endif
+#ifndef AI_ALL
+# define AI_ALL 0x00000100
+#endif
+#ifndef AI_ADDRCONFIG
+# define AI_ADDRCONFIG 0x00000400
+#endif
+#ifndef AI_V4MAPPED
+# define AI_V4MAPPED 0x00000800
+#endif")
+
+file(READ ${LUV_SRC_DIR}/src/dns.c LUV_SRC_DNS_C)
+string(REPLACE
+  "\n#include <netdb.h>"
+  "\n#include <netdb.h>\n#else\n${LUV_SRC_DNS_C_DEFS}"
+  LUV_SRC_DNS_C_PATCHED
+  "${LUV_SRC_DNS_C}")
+file(WRITE ${LUV_SRC_DIR}/src/dns.c "${LUV_SRC_DNS_C_PATCHED}")
+