From 905dd49fece0903dba4e5a618f503d0237415b14 Mon Sep 17 00:00:00 2001
From: Thomas Vigouroux <tomvig38@gmail.com>
Date: Mon, 16 Aug 2021 15:37:01 +0200
Subject: feat(treesitter): bundle Lua parser and queries

parser from https://github.com/MunifTanjim/tree-sitter-lua
queries from nvim-treesitter
---
 runtime/queries/lua/highlights.scm | 192 +++++++++++++++++++++++++++++++++++++
 1 file changed, 192 insertions(+)
 create mode 100644 runtime/queries/lua/highlights.scm

(limited to 'runtime/queries')

diff --git a/runtime/queries/lua/highlights.scm b/runtime/queries/lua/highlights.scm
new file mode 100644
index 0000000000..92baba0f39
--- /dev/null
+++ b/runtime/queries/lua/highlights.scm
@@ -0,0 +1,192 @@
+;; Keywords
+
+"return" @keyword.return
+
+[
+ "goto"
+ "in"
+ "local"
+] @keyword
+
+(label_statement) @label
+
+(break_statement) @keyword
+
+(do_statement
+[
+  "do"
+  "end"
+] @keyword)
+
+(while_statement
+[
+  "while"
+  "do"
+  "end"
+] @repeat)
+
+(repeat_statement
+[
+  "repeat"
+  "until"
+] @repeat)
+
+(if_statement
+[
+  "if"
+  "elseif"
+  "else"
+  "then"
+  "end"
+] @conditional)
+
+(elseif_statement
+[
+  "elseif"
+  "then"
+  "end"
+] @conditional)
+
+(else_statement
+[
+  "else"
+  "end"
+] @conditional)
+
+(for_statement
+[
+  "for"
+  "do"
+  "end"
+] @repeat)
+
+(function_declaration
+[
+  "function"
+  "end"
+] @keyword.function)
+
+(function_definition
+[
+  "function"
+  "end"
+] @keyword.function)
+
+;; Operators
+
+[
+ "and"
+ "not"
+ "or"
+] @keyword.operator
+
+[
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "^"
+  "#"
+  "=="
+  "~="
+  "<="
+  ">="
+  "<"
+  ">"
+  "="
+  "&"
+  "~"
+  "|"
+  "<<"
+  ">>"
+  "//"
+  ".."
+] @operator
+
+;; Punctuations
+
+[
+  ";"
+  ":"
+  ","
+  "."
+] @punctuation.delimiter
+
+;; Brackets
+
+[
+ "("
+ ")"
+ "["
+ "]"
+ "{"
+ "}"
+] @punctuation.bracket
+
+;; Variables
+
+(identifier) @variable
+
+((identifier) @variable.builtin
+ (#eq? @variable.builtin "self"))
+
+;; Constants
+
+((identifier) @constant
+ (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+(vararg_expression) @constant
+
+(nil) @constant.builtin
+
+[
+  (false)
+  (true)
+] @boolean
+
+;; Tables
+
+(field name: (identifier) @field)
+
+(dot_index_expression field: (identifier) @field)
+
+(table_constructor
+[
+  "{"
+  "}"
+] @constructor)
+
+;; Functions
+
+(parameters (identifier) @parameter)
+
+(function_call name: (identifier) @function.call)
+(function_declaration name: (identifier) @function)
+
+(function_call name: (dot_index_expression field: (identifier) @function.call))
+(function_declaration name: (dot_index_expression field: (identifier) @function))
+
+(method_index_expression method: (identifier) @method)
+
+(function_call
+  (identifier) @function.builtin
+  (#any-of? @function.builtin
+    ;; built-in functions in Lua 5.1
+    "assert" "collectgarbage" "dofile" "error" "getfenv" "getmetatable" "ipairs"
+    "load" "loadfile" "loadstring" "module" "next" "pairs" "pcall" "print"
+    "rawequal" "rawget" "rawset" "require" "select" "setfenv" "setmetatable"
+    "tonumber" "tostring" "type" "unpack" "xpcall"))
+
+;; Others
+
+(comment) @comment
+
+(hash_bang_line) @comment
+
+(number) @number
+
+(string) @string
+
+;; Error
+(ERROR) @error
-- 
cgit 


From e85b8aa7681a1870244795cccfbb74b589996eff Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Sun, 4 Sep 2022 16:27:57 +0200
Subject: feat(treesitter): add viml parser and queries

---
 runtime/queries/vim/highlights.scm | 245 +++++++++++++++++++++++++++++++++++++
 1 file changed, 245 insertions(+)
 create mode 100644 runtime/queries/vim/highlights.scm

(limited to 'runtime/queries')

diff --git a/runtime/queries/vim/highlights.scm b/runtime/queries/vim/highlights.scm
new file mode 100644
index 0000000000..c02e226b66
--- /dev/null
+++ b/runtime/queries/vim/highlights.scm
@@ -0,0 +1,245 @@
+(identifier) @variable
+((identifier) @constant
+ (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+;; Keywords
+
+[
+  "if"
+  "else"
+  "elseif"
+  "endif"
+] @conditional
+
+[
+  "try"
+  "catch"
+  "finally"
+  "endtry"
+  "throw"
+] @exception
+
+[
+  "for"
+  "endfor"
+  "in"
+  "while"
+  "endwhile"
+  "break"
+  "continue"
+] @repeat
+
+[
+  "function"
+  "endfunction"
+] @keyword.function
+
+;; Function related
+(function_declaration name: (_) @function)
+(call_expression function: (identifier) @function)
+(parameters (identifier) @parameter)
+(default_parameter (identifier) @parameter)
+
+[ (bang) (spread) (at) ] @punctuation.special
+
+[ (no_option) (inv_option) (default_option) (option_name) ] @variable.builtin
+[
+  (scope)
+  "a:"
+  "$"
+] @namespace
+
+;; Commands and user defined commands
+
+[
+  "let"
+  "unlet"
+  "const"
+  "call"
+  "execute"
+  "normal"
+  "set"
+  "setlocal"
+  "silent"
+  "echo"
+  "echomsg"
+  "autocmd"
+  "augroup"
+  "return"
+  "syntax"
+  "lua"
+  "ruby"
+  "perl"
+  "python"
+  "highlight"
+  "command"
+  "delcommand"
+  "comclear"
+  "colorscheme"
+  "startinsert"
+  "stopinsert"
+  "global"
+  "runtime"
+  "wincmd"
+  "cnext"
+  "cprevious"
+  "cNext"
+  "vertical"
+  "leftabove"
+  "aboveleft"
+  "rightbelow"
+  "belowright"
+  "topleft"
+  "botright"
+  (unknown_command_name)
+] @keyword
+(map_statement cmd: _ @keyword)
+(command_name) @function.macro
+
+;; Syntax command
+
+(syntax_statement (keyword) @string)
+(syntax_statement [
+  "enable"
+  "on"
+  "off"
+  "reset"
+  "case"
+  "spell"
+  "foldlevel"
+  "iskeyword"
+  "keyword"
+  "match"
+  "cluster"
+  "region"
+] @keyword)
+
+(syntax_argument name: _ @keyword)
+
+[
+  "<buffer>"
+  "<nowait>"
+  "<silent>"
+  "<script>"
+  "<expr>"
+  "<unique>"
+] @constant.builtin
+
+(hl_attribute
+  key: _ @property
+  val: _ @constant)
+
+(hl_group) @variable
+(augroup_name) @namespace
+
+(au_event) @constant
+(normal_statement (commands) @constant)
+
+;; Highlight command
+
+(highlight_statement [
+  "default"
+  "link"
+  "clear"
+] @keyword)
+
+;; Command command
+
+(command_attribute
+  name: _ @property
+  val: (behavior
+    name: _ @constant
+    val: (identifier)? @function)?)
+
+;; Runtime command
+
+(runtime_statement (where) @keyword.operator)
+
+;; Colorscheme command
+
+(colorscheme_statement (name) @string)
+
+;; Literals
+
+(string_literal) @string
+(integer_literal) @number
+(float_literal) @float
+(comment) @comment
+(pattern) @string.special
+(pattern_multi) @string.regex
+(filename) @string
+(heredoc (body) @string)
+((heredoc (parameter) @keyword))
+((scoped_identifier
+  (scope) @_scope . (identifier) @boolean)
+ (#eq? @_scope "v:")
+ (#any-of? @boolean "true" "false"))
+
+;; Operators
+
+[
+  "||"
+  "&&"
+  "&"
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  ".."
+  "is"
+  "isnot"
+  "=="
+  "!="
+  ">"
+  ">="
+  "<"
+  "<="
+  "=~"
+  "!~"
+  "="
+  "+="
+  "-="
+  "*="
+  "/="
+  "%="
+  ".="
+  "..="
+] @operator
+
+; Some characters have different meanings based on the context
+(unary_operation "!" @operator)
+(binary_operation "." @operator)
+
+;; Punctuation
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+(field_expression "." @punctuation.delimiter)
+
+[
+  ","
+  ":"
+] @punctuation.delimiter
+
+(ternary_expression ["?" ":"] @conditional)
+
+; Options
+((set_value) @number
+ (#match? @number "^[0-9]+(\.[0-9]+)?$"))
+
+((set_item
+   option: (option_name) @_option
+   value: (set_value) @function)
+  (#any-of? @_option
+    "tagfunc" "tfu"
+    "completefunc" "cfu"
+    "omnifunc" "ofu"
+    "operatorfunc" "opfunc"))
-- 
cgit 


From 64cc78c9f39b3066b74f01ec7e3f50fd316416e4 Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Sun, 4 Sep 2022 16:37:24 +0200
Subject: feat(treesitter): add injections

---
 runtime/queries/c/injections.scm   |  3 +++
 runtime/queries/lua/injections.scm | 22 ++++++++++++++++++++++
 runtime/queries/vim/injections.scm | 26 ++++++++++++++++++++++++++
 3 files changed, 51 insertions(+)
 create mode 100644 runtime/queries/c/injections.scm
 create mode 100644 runtime/queries/lua/injections.scm
 create mode 100644 runtime/queries/vim/injections.scm

(limited to 'runtime/queries')

diff --git a/runtime/queries/c/injections.scm b/runtime/queries/c/injections.scm
new file mode 100644
index 0000000000..7e9e73449d
--- /dev/null
+++ b/runtime/queries/c/injections.scm
@@ -0,0 +1,3 @@
+(preproc_arg) @c
+
+; (comment) @comment
diff --git a/runtime/queries/lua/injections.scm b/runtime/queries/lua/injections.scm
new file mode 100644
index 0000000000..0e67329139
--- /dev/null
+++ b/runtime/queries/lua/injections.scm
@@ -0,0 +1,22 @@
+((function_call
+  name: [
+    (identifier) @_cdef_identifier
+    (_ _ (identifier) @_cdef_identifier)
+  ]
+  arguments: (arguments (string content: _ @c)))
+  (#eq? @_cdef_identifier "cdef"))
+
+((function_call
+  name: (_) @_vimcmd_identifier
+  arguments: (arguments (string content: _ @vim)))
+  (#any-of? @_vimcmd_identifier "vim.cmd" "vim.api.nvim_command" "vim.api.nvim_exec" "vim.api.nvim_cmd"))
+
+; ((function_call
+;   name: (_) @_vimcmd_identifier
+;   arguments: (arguments (string content: _ @query) .))
+;   (#eq? @_vimcmd_identifier "vim.treesitter.query.set_query"))
+
+; ;; highlight string as query if starts with `;; query`
+; ((string ("string_content") @query) (#lua-match? @query "^%s*;+%s?query"))
+
+; (comment) @comment
diff --git a/runtime/queries/vim/injections.scm b/runtime/queries/vim/injections.scm
new file mode 100644
index 0000000000..e2dea8fe75
--- /dev/null
+++ b/runtime/queries/vim/injections.scm
@@ -0,0 +1,26 @@
+(lua_statement (script (body) @lua))
+(lua_statement (chunk) @lua)
+; (ruby_statement (script (body) @ruby))
+; (ruby_statement (chunk) @ruby)
+; (python_statement (script (body) @python))
+; (python_statement (chunk) @python)
+;; (perl_statement (script (body) @perl))
+;; (perl_statement (chunk) @perl)
+
+; (autocmd_statement (pattern) @regex)
+
+((set_item
+   option: (option_name) @_option
+   value: (set_value) @vim)
+  (#any-of? @_option
+    "includeexpr" "inex"
+    "printexpr" "pexpr"
+    "formatexpr" "fex"
+    "indentexpr" "inde"
+    "foldtext" "fdt"
+    "foldexpr" "fde"
+    "diffexpr" "dex"
+    "patchexpr" "pex"
+    "charconvert" "ccv"))
+
+; (comment) @comment
-- 
cgit 


From 75adfefc85bcf0d62d2c0f51a951e6003b595cea Mon Sep 17 00:00:00 2001
From: Thomas Vigouroux <thomas.vigouroux@protonmail.com>
Date: Mon, 18 Jul 2022 14:21:40 +0200
Subject: feat(extmarks,ts,spell): full support for spelling
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

- Added 'spell' option to extmarks:

  Extmarks with this set will have the region spellchecked.

- Added 'noplainbuffer' option to 'spelloptions':

  This is used to tell Neovim not to spellcheck the buffer. The old
  behaviour was to spell check the whole buffer unless :syntax was set.

- Added spelling support to the treesitter highlighter:

  @spell captures in highlights.scm are used to define regions which
  should be spell checked.

- Added support for navigating spell errors for extmarks:

  Works for both ephemeral and static extmarks

- Added '_on_spell_nav' callback for decoration providers:

  Since ephemeral callbacks are only drawn for the visible screen,
  providers must implement this callback to instruct Neovim which
  regions in the buffer need can be spell checked.

  The callback takes a start position and an end position.

  Note: this callback is subject to change hence the _ prefix.

- Added spell captures for built-in support languages

Co-authored-by: Lewis Russell <lewis6991@gmail.com>
Co-authored-by: Björn Linse <bjorn.linse@gmail.com>
---
 runtime/queries/c/highlights.scm   | 2 ++
 runtime/queries/lua/highlights.scm | 2 ++
 runtime/queries/vim/highlights.scm | 2 ++
 3 files changed, 6 insertions(+)

(limited to 'runtime/queries')

diff --git a/runtime/queries/c/highlights.scm b/runtime/queries/c/highlights.scm
index 260750a85b..33e6df74ab 100644
--- a/runtime/queries/c/highlights.scm
+++ b/runtime/queries/c/highlights.scm
@@ -101,6 +101,7 @@
 [ "(" ")" "[" "]" "{" "}"] @punctuation.bracket
 
 (string_literal) @string
+(string_literal) @spell
 (system_lib_string) @string
 
 (null) @constant.builtin
@@ -148,6 +149,7 @@
 
 
 (comment) @comment
+(comment) @spell
 
 ;; Parameters
 (parameter_declaration
diff --git a/runtime/queries/lua/highlights.scm b/runtime/queries/lua/highlights.scm
index 92baba0f39..054d787932 100644
--- a/runtime/queries/lua/highlights.scm
+++ b/runtime/queries/lua/highlights.scm
@@ -181,12 +181,14 @@
 ;; Others
 
 (comment) @comment
+(comment) @spell
 
 (hash_bang_line) @comment
 
 (number) @number
 
 (string) @string
+(string) @spell
 
 ;; Error
 (ERROR) @error
diff --git a/runtime/queries/vim/highlights.scm b/runtime/queries/vim/highlights.scm
index c02e226b66..1bbaebef01 100644
--- a/runtime/queries/vim/highlights.scm
+++ b/runtime/queries/vim/highlights.scm
@@ -162,9 +162,11 @@
 ;; Literals
 
 (string_literal) @string
+(string_literal) @spell
 (integer_literal) @number
 (float_literal) @float
 (comment) @comment
+(comment) @spell
 (pattern) @string.special
 (pattern_multi) @string.regex
 (filename) @string
-- 
cgit 


From 79a9b0067131d264d79cf15ce50e04ff14c2c816 Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Thu, 8 Sep 2022 19:46:40 +0200
Subject: build(deps): bump tree-sitter-viml to 0.2.0 (#20121)

---
 runtime/queries/vim/highlights.scm | 32 ++++++++++++++++++++++----------
 1 file changed, 22 insertions(+), 10 deletions(-)

(limited to 'runtime/queries')

diff --git a/runtime/queries/vim/highlights.scm b/runtime/queries/vim/highlights.scm
index 1bbaebef01..3d1729b2cd 100644
--- a/runtime/queries/vim/highlights.scm
+++ b/runtime/queries/vim/highlights.scm
@@ -40,7 +40,7 @@
 (parameters (identifier) @parameter)
 (default_parameter (identifier) @parameter)
 
-[ (bang) (spread) (at) ] @punctuation.special
+[ (bang) (spread) ] @punctuation.special
 
 [ (no_option) (inv_option) (default_option) (option_name) ] @variable.builtin
 [
@@ -92,6 +92,12 @@
   "topleft"
   "botright"
   (unknown_command_name)
+  "edit"
+  "enew"
+  "find"
+  "ex"
+  "visual"
+  "view"
 ] @keyword
 (map_statement cmd: _ @keyword)
 (command_name) @function.macro
@@ -125,11 +131,6 @@
   "<unique>"
 ] @constant.builtin
 
-(hl_attribute
-  key: _ @property
-  val: _ @constant)
-
-(hl_group) @variable
 (augroup_name) @namespace
 
 (au_event) @constant
@@ -137,6 +138,12 @@
 
 ;; Highlight command
 
+(hl_attribute
+  key: _ @property
+  val: _ @constant)
+
+(hl_group) @type
+
 (highlight_statement [
   "default"
   "link"
@@ -145,12 +152,19 @@
 
 ;; Command command
 
+(command) @string
+
 (command_attribute
   name: _ @property
   val: (behavior
     name: _ @constant
     val: (identifier)? @function)?)
 
+;; Edit command
+(plus_plus_opt
+  val: _? @constant) @property
+(plus_cmd "+" @property) @property
+
 ;; Runtime command
 
 (runtime_statement (where) @keyword.operator)
@@ -161,12 +175,10 @@
 
 ;; Literals
 
-(string_literal) @string
-(string_literal) @spell
+(string_literal) @string @spell
 (integer_literal) @number
 (float_literal) @float
-(comment) @comment
-(comment) @spell
+(comment) @comment @spell
 (pattern) @string.special
 (pattern_multi) @string.regex
 (filename) @string
-- 
cgit 


From bde6176c9107e32466f28dc96e9a71fd4d7bb644 Mon Sep 17 00:00:00 2001
From: "Justin M. Keyes" <justinkz@gmail.com>
Date: Thu, 8 Sep 2022 14:26:18 -0700
Subject: feat(treesitter): bundle :help parser and queries

parser from https://github.com/vigoux/tree-sitter-vimdoc
queries from nvim-treesitter
---
 runtime/queries/help/highlights.scm | 14 ++++++++++++++
 1 file changed, 14 insertions(+)
 create mode 100644 runtime/queries/help/highlights.scm

(limited to 'runtime/queries')

diff --git a/runtime/queries/help/highlights.scm b/runtime/queries/help/highlights.scm
new file mode 100644
index 0000000000..41c78a7f1c
--- /dev/null
+++ b/runtime/queries/help/highlights.scm
@@ -0,0 +1,14 @@
+(headline) @text.title
+(column_heading) @text.title
+(tag
+   "*" @conceal (#set! conceal "")
+   name: (_) @label)
+(option
+   name: (_) @text.literal)
+(hotlink
+   "|" @conceal (#set! conceal "")
+   destination: (_) @text.reference)
+(backtick
+   "`" @conceal (#set! conceal "")
+   content: (_) @string)
+(argument) @parameter
-- 
cgit 


From a5effcedd2888298fda62947410316c080e9a4dc Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Wed, 28 Sep 2022 16:29:35 +0200
Subject: build(deps): bump help parser and queries (#20388)

---
 runtime/queries/help/highlights.scm | 18 ++++++++++--------
 1 file changed, 10 insertions(+), 8 deletions(-)

(limited to 'runtime/queries')

diff --git a/runtime/queries/help/highlights.scm b/runtime/queries/help/highlights.scm
index 41c78a7f1c..6be4e49c81 100644
--- a/runtime/queries/help/highlights.scm
+++ b/runtime/queries/help/highlights.scm
@@ -1,14 +1,16 @@
-(headline) @text.title
+(h1) @text.title
+(h2) @text.title
+(h3) @text.title
 (column_heading) @text.title
 (tag
    "*" @conceal (#set! conceal "")
-   name: (_) @label)
-(option
-   name: (_) @text.literal)
-(hotlink
+   text: (_) @label)
+(taglink
    "|" @conceal (#set! conceal "")
-   destination: (_) @text.reference)
-(backtick
+   text: (_) @text.reference)
+(optionlink
+   text: (_) @text.literal)
+(codespan
    "`" @conceal (#set! conceal "")
-   content: (_) @string)
+   text: (_) @string)
 (argument) @parameter
-- 
cgit 


From d339b4aad7461937e1e03ac0836b2eb1354ff442 Mon Sep 17 00:00:00 2001
From: "Justin M. Keyes" <justinkz@gmail.com>
Date: Thu, 13 Oct 2022 21:36:25 -0400
Subject: build(deps): bump vimdoc (help) parser to v1.2.1 #20642

---
 runtime/queries/help/highlights.scm | 7 +++++--
 1 file changed, 5 insertions(+), 2 deletions(-)

(limited to 'runtime/queries')

diff --git a/runtime/queries/help/highlights.scm b/runtime/queries/help/highlights.scm
index 6be4e49c81..cd4b6f8269 100644
--- a/runtime/queries/help/highlights.scm
+++ b/runtime/queries/help/highlights.scm
@@ -9,8 +9,11 @@
    "|" @conceal (#set! conceal "")
    text: (_) @text.reference)
 (optionlink
-   text: (_) @text.literal)
+   text: (_) @text.reference)
 (codespan
    "`" @conceal (#set! conceal "")
-   text: (_) @string)
+   text: (_) @text.literal)
+(codeblock) @text.literal
 (argument) @parameter
+(keycode) @string.special
+(url) @text.uri
-- 
cgit 


From 29fe3348ba126a334d7e6f06a66f14ec3110d02f Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 24 Oct 2022 09:35:00 +0200
Subject: build(deps): bump vimdoc parser and queries to v1.2.4 (#20788)

---
 runtime/queries/help/highlights.scm | 4 ++++
 1 file changed, 4 insertions(+)

(limited to 'runtime/queries')

diff --git a/runtime/queries/help/highlights.scm b/runtime/queries/help/highlights.scm
index cd4b6f8269..50beeed8b9 100644
--- a/runtime/queries/help/highlights.scm
+++ b/runtime/queries/help/highlights.scm
@@ -14,6 +14,10 @@
    "`" @conceal (#set! conceal "")
    text: (_) @text.literal)
 (codeblock) @text.literal
+(codeblock
+   ">" @conceal (#set! conceal ""))
+(block
+   "<" @conceal (#set! conceal ""))
 (argument) @parameter
 (keycode) @string.special
 (url) @text.uri
-- 
cgit 


From dab07be4d14b3d4d94cbab2bdc29d3e6985e21f2 Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Thu, 27 Oct 2022 09:16:16 +0200
Subject: build(deps): bump vimdoc parser to v1.2.5 (#20829)

---
 runtime/queries/help/highlights.scm | 2 ++
 1 file changed, 2 insertions(+)

(limited to 'runtime/queries')

diff --git a/runtime/queries/help/highlights.scm b/runtime/queries/help/highlights.scm
index 50beeed8b9..b2ed390336 100644
--- a/runtime/queries/help/highlights.scm
+++ b/runtime/queries/help/highlights.scm
@@ -2,6 +2,8 @@
 (h2) @text.title
 (h3) @text.title
 (column_heading) @text.title
+(column_heading
+   "~" @conceal (#set! conceal ""))
 (tag
    "*" @conceal (#set! conceal "")
    text: (_) @label)
-- 
cgit 


From 582c044dbe2b2bc4c74212b5ed8660c20fa1fd99 Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Tue, 1 Nov 2022 13:38:47 +0100
Subject: build(deps): bump lua parser to v0.0.14 (#20897)

---
 runtime/queries/lua/highlights.scm | 5 +++++
 1 file changed, 5 insertions(+)

(limited to 'runtime/queries')

diff --git a/runtime/queries/lua/highlights.scm b/runtime/queries/lua/highlights.scm
index 054d787932..2c0dc5447a 100644
--- a/runtime/queries/lua/highlights.scm
+++ b/runtime/queries/lua/highlights.scm
@@ -131,6 +131,11 @@
 ((identifier) @variable.builtin
  (#eq? @variable.builtin "self"))
 
+(variable_list
+  attribute: (attribute
+    (["<" ">"] @punctuation.bracket
+     (identifier) @attribute)))
+
 ;; Constants
 
 ((identifier) @constant
-- 
cgit 


From 915891f28c3bd51007ea4105db82c62c17177115 Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Tue, 22 Nov 2022 21:25:51 +0100
Subject: build(deps): update viml parser and queries (#21158)

---
 runtime/queries/vim/highlights.scm | 37 ++++++++++++++++++++++++++++++++++---
 runtime/queries/vim/injections.scm | 14 ++++++++------
 2 files changed, 42 insertions(+), 9 deletions(-)

(limited to 'runtime/queries')

diff --git a/runtime/queries/vim/highlights.scm b/runtime/queries/vim/highlights.scm
index 3d1729b2cd..239b0a0b37 100644
--- a/runtime/queries/vim/highlights.scm
+++ b/runtime/queries/vim/highlights.scm
@@ -36,7 +36,8 @@
 
 ;; Function related
 (function_declaration name: (_) @function)
-(call_expression function: (identifier) @function)
+(call_expression function: (identifier) @function.call)
+(call_expression function: (scoped_identifier (identifier) @function.call))
 (parameters (identifier) @parameter)
 (default_parameter (identifier) @parameter)
 
@@ -59,14 +60,20 @@
   "execute"
   "normal"
   "set"
+  "setfiletype"
   "setlocal"
   "silent"
   "echo"
+  "echon"
+  "echohl"
   "echomsg"
+  "echoerr"
   "autocmd"
   "augroup"
   "return"
   "syntax"
+  "filetype"
+  "source"
   "lua"
   "ruby"
   "perl"
@@ -98,10 +105,21 @@
   "ex"
   "visual"
   "view"
+  "eval"
 ] @keyword
 (map_statement cmd: _ @keyword)
 (command_name) @function.macro
 
+;; Filetype command
+
+(filetype_statement [
+  "detect"
+  "plugin"
+  "indent"
+  "on"
+  "off"
+] @keyword)
+
 ;; Syntax command
 
 (syntax_statement (keyword) @string)
@@ -118,6 +136,8 @@
   "match"
   "cluster"
   "region"
+  "clear"
+  "include"
 ] @keyword)
 
 (syntax_argument name: _ @keyword)
@@ -175,15 +195,18 @@
 
 ;; Literals
 
-(string_literal) @string @spell
+(string_literal) @string
 (integer_literal) @number
 (float_literal) @float
 (comment) @comment @spell
+(line_continuation_comment) @comment @spell
 (pattern) @string.special
 (pattern_multi) @string.regex
 (filename) @string
 (heredoc (body) @string)
-((heredoc (parameter) @keyword))
+(heredoc (parameter) @keyword)
+[ (marker_definition) (endmarker) ] @label
+(literal_dictionary (literal_key) @label)
 ((scoped_identifier
   (scope) @_scope . (identifier) @boolean)
  (#eq? @_scope "v:")
@@ -219,12 +242,16 @@
   "%="
   ".="
   "..="
+  "<<"
+  "=<<"
+  (match_case)
 ] @operator
 
 ; Some characters have different meanings based on the context
 (unary_operation "!" @operator)
 (binary_operation "." @operator)
 
+
 ;; Punctuation
 
 [
@@ -234,6 +261,7 @@
   "}"
   "["
   "]"
+  "#{"
 ] @punctuation.bracket
 
 (field_expression "." @punctuation.delimiter)
@@ -249,6 +277,9 @@
 ((set_value) @number
  (#match? @number "^[0-9]+(\.[0-9]+)?$"))
 
+(inv_option "!" @operator)
+(set_item "?" @operator)
+
 ((set_item
    option: (option_name) @_option
    value: (set_value) @function)
diff --git a/runtime/queries/vim/injections.scm b/runtime/queries/vim/injections.scm
index e2dea8fe75..fdd025bfd9 100644
--- a/runtime/queries/vim/injections.scm
+++ b/runtime/queries/vim/injections.scm
@@ -1,13 +1,14 @@
 (lua_statement (script (body) @lua))
 (lua_statement (chunk) @lua)
-; (ruby_statement (script (body) @ruby))
-; (ruby_statement (chunk) @ruby)
-; (python_statement (script (body) @python))
-; (python_statement (chunk) @python)
+(ruby_statement (script (body) @ruby))
+(ruby_statement (chunk) @ruby)
+(python_statement (script (body) @python))
+(python_statement (chunk) @python)
+;; If we support perl at some point...
 ;; (perl_statement (script (body) @perl))
 ;; (perl_statement (chunk) @perl)
 
-; (autocmd_statement (pattern) @regex)
+(autocmd_statement (pattern) @regex)
 
 ((set_item
    option: (option_name) @_option
@@ -23,4 +24,5 @@
     "patchexpr" "pex"
     "charconvert" "ccv"))
 
-; (comment) @comment
+(comment) @comment
+(line_continuation_comment) @comment
-- 
cgit 


From 5093f38c9fed9fae04234035ea253862ba8375ef Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Tue, 22 Nov 2022 13:50:50 +0100
Subject: feat(help): highlighted codeblocks

---
 runtime/queries/help/highlights.scm | 2 +-
 runtime/queries/help/injections.scm | 3 +++
 2 files changed, 4 insertions(+), 1 deletion(-)
 create mode 100644 runtime/queries/help/injections.scm

(limited to 'runtime/queries')

diff --git a/runtime/queries/help/highlights.scm b/runtime/queries/help/highlights.scm
index b2ed390336..c0d88301bc 100644
--- a/runtime/queries/help/highlights.scm
+++ b/runtime/queries/help/highlights.scm
@@ -17,7 +17,7 @@
    text: (_) @text.literal)
 (codeblock) @text.literal
 (codeblock
-   ">" @conceal (#set! conceal ""))
+   [">" (language)] @conceal (#set! conceal ""))
 (block
    "<" @conceal (#set! conceal ""))
 (argument) @parameter
diff --git a/runtime/queries/help/injections.scm b/runtime/queries/help/injections.scm
new file mode 100644
index 0000000000..09bbe44e84
--- /dev/null
+++ b/runtime/queries/help/injections.scm
@@ -0,0 +1,3 @@
+(codeblock
+  (language) @language
+  (code) @content)
-- 
cgit