alacritty/res/gles2/text.f.glsl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

varying mediump vec2 TexCoords;
varying mediump vec3 fg;
varying highp float colored;
varying mediump vec4 bg;

uniform highp int renderingPass;
uniform sampler2D mask;

#define COLORED 1

mediump float max_rgb(mediump vec3 mask) {
    return max(max(mask.r, mask.g), mask.b);
}

void render_text() {
    mediump vec4 mask = texture2D(mask, TexCoords);
    mediump float m_rgb = max_rgb(mask.rgb);

    if (renderingPass == 1) {
        gl_FragColor = vec4(mask.rgb, m_rgb);
    } else if (renderingPass == 2) {
        gl_FragColor = bg * (vec4(m_rgb) - vec4(mask.rgb, m_rgb));
    } else {
        gl_FragColor = vec4(fg, 1.) * vec4(mask.rgb, m_rgb);
    }
}

// Render colored bitmaps.
void render_bitmap() {
    if (renderingPass == 2) {
        discard;
    }
    mediump vec4 mask = texture2D(mask, TexCoords);
    if (renderingPass == 1) {
        gl_FragColor = mask.aaaa;
    } else {
        gl_FragColor = mask;
    }
}

void main() {
    // Handle background pass drawing before anything else.
    if (renderingPass == 0) {
        if (bg.a == 0.0) {
            discard;
        }

        gl_FragColor = vec4(bg.rgb * bg.a, bg.a);
        return;
    }

    if (int(colored) == COLORED) {
        render_bitmap();
    } else {
        render_text();
    }
}