feat(treesitter)!: new standard capture names

Problem: Sharing queries with upstream and Helix is difficult due to
different capture names.

Solution: Define and document a new set of standard captures that
matches tree-sitter "standard captures" (where defined) and is closer to
Helix' Atom-style nested groups.

This is a breaking change for colorschemes that defined highlights based
on the old captures. On the other hand, the default colorscheme now
defines links for all standard captures (not just those used in bundled
queries), improving the out-of-the-box experience.

3 files changed, 257 insertions, 134 deletions

diff --git a/runtime/queries/lua/folds.scm b/runtime/queries/lua/folds.scm
index d8f0b42df3..9dfac3abc6 100644
--- a/runtime/queries/lua/folds.scm
+++ b/runtime/queries/lua/folds.scm
@@ -1,10 +1,12 @@
 [
- (do_statement)
- (while_statement)
- (repeat_statement)
- (if_statement)
- (for_statement)
- (function_declaration)
- (function_definition)
- (table_constructor)
+  (do_statement)
+  (while_statement)
+  (repeat_statement)
+  (if_statement)
+  (for_statement)
+  (function_declaration)
+  (function_definition)
+  (parameters)
+  (arguments)
+  (table_constructor)
 ] @fold
diff --git a/runtime/queries/lua/highlights.scm b/runtime/queries/lua/highlights.scm
index 96ffeae793..0b0bf35a8b 100644
--- a/runtime/queries/lua/highlights.scm
+++ b/runtime/queries/lua/highlights.scm
@@ -1,81 +1,79 @@
-;; Keywords
-
+; Keywords
 "return" @keyword.return
 
 [
- "goto"
- "in"
- "local"
+  "goto"
+  "in"
+  "local"
 ] @keyword
 
 (break_statement) @keyword
 
 (do_statement
-[
-  "do"
-  "end"
-] @keyword)
+  [
+    "do"
+    "end"
+  ] @keyword)
 
 (while_statement
-[
-  "while"
-  "do"
-  "end"
-] @repeat)
+  [
+    "while"
+    "do"
+    "end"
+  ] @keyword.repeat)
 
 (repeat_statement
-[
-  "repeat"
-  "until"
-] @repeat)
+  [
+    "repeat"
+    "until"
+  ] @keyword.repeat)
 
 (if_statement
-[
-  "if"
-  "elseif"
-  "else"
-  "then"
-  "end"
-] @conditional)
+  [
+    "if"
+    "elseif"
+    "else"
+    "then"
+    "end"
+  ] @keyword.conditional)
 
 (elseif_statement
-[
-  "elseif"
-  "then"
-  "end"
-] @conditional)
+  [
+    "elseif"
+    "then"
+    "end"
+  ] @keyword.conditional)
 
 (else_statement
-[
-  "else"
-  "end"
-] @conditional)
+  [
+    "else"
+    "end"
+  ] @keyword.conditional)
 
 (for_statement
-[
-  "for"
-  "do"
-  "end"
-] @repeat)
+  [
+    "for"
+    "do"
+    "end"
+  ] @keyword.repeat)
 
 (function_declaration
-[
-  "function"
-  "end"
-] @keyword.function)
+  [
+    "function"
+    "end"
+  ] @keyword.function)
 
 (function_definition
-[
-  "function"
-  "end"
-] @keyword.function)
-
-;; Operators
+  [
+    "function"
+    "end"
+  ] @keyword.function)
 
+; Operators
 [
- "and"
- "not"
- "or"
+  "and"
+  "not"
+  "or"
 ] @keyword.operator
 
 [
@@ -102,8 +100,7 @@
   ".."
 ] @operator
 
-;; Punctuations
-
+; Punctuations
 [
   ";"
   ":"
@@ -112,19 +109,17 @@
   "."
 ] @punctuation.delimiter
 
-;; Brackets
-
+; Brackets
 [
- "("
- ")"
- "["
- "]"
- "{"
- "}"
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
 ] @punctuation.bracket
 
-;; Variables
-
+; Variables
 (identifier) @variable
 
 ((identifier) @constant.builtin
@@ -133,27 +128,28 @@
 ((identifier) @variable.builtin
   (#eq? @variable.builtin "self"))
 
-((identifier) @namespace.builtin
-  (#any-of? @namespace.builtin "_G" "debug" "io" "jit" "math" "os" "package" "string" "table" "utf8"))
+((identifier) @module.builtin
+  (#any-of? @module.builtin "_G" "debug" "io" "jit" "math" "os" "package" "string" "table" "utf8"))
 
 ((identifier) @keyword.coroutine
   (#eq? @keyword.coroutine "coroutine"))
 
 (variable_list
-   attribute: (attribute
-     (["<" ">"] @punctuation.bracket
-      (identifier) @attribute)))
-
-;; Labels
+  (attribute
+    "<" @punctuation.bracket
+    (identifier) @attribute
+    ">" @punctuation.bracket))
 
-(label_statement (identifier) @label)
+; Labels
+(label_statement
+  (identifier) @label)
 
-(goto_statement (identifier) @label)
-
-;; Constants
+(goto_statement
+  (identifier) @label)
 
+; Constants
 ((identifier) @constant
- (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+  (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
 
 (vararg_expression) @constant
 
@@ -164,41 +160,49 @@
   (true)
 ] @boolean
 
-;; Tables
-
-(field name: (identifier) @field)
+; Tables
+(field
+  name: (identifier) @variable.member)
 
-(dot_index_expression field: (identifier) @field)
+(dot_index_expression
+  field: (identifier) @variable.member)
 
 (table_constructor
-[
-  "{"
-  "}"
-] @constructor)
+  [
+    "{"
+    "}"
+  ] @constructor)
 
-;; Functions
+; Functions
+(parameters
+  (identifier) @variable.parameter)
 
-(parameters (identifier) @parameter)
-
-(function_declaration
-  name: [
-    (identifier) @function
-    (dot_index_expression
-      field: (identifier) @function)
-  ])
+(vararg_expression) @variable.parameter.builtin
 
 (function_declaration
-  name: (method_index_expression
-    method: (identifier) @method))
-
-(assignment_statement
-  (variable_list .
-    name: [
+  name:
+    [
       (identifier) @function
       (dot_index_expression
         field: (identifier) @function)
     ])
-  (expression_list .
+
+(function_declaration
+  name:
+    (method_index_expression
+      method: (identifier) @function.method))
+
+(assignment_statement
+  (variable_list
+    .
+    name:
+      [
+        (identifier) @function
+        (dot_index_expression
+          field: (identifier) @function)
+      ])
+  (expression_list
+    .
     value: (function_definition)))
 
 (table_constructor
@@ -207,18 +211,20 @@
     value: (function_definition)))
 
 (function_call
-  name: [
-    (identifier) @function.call
-    (dot_index_expression
-      field: (identifier) @function.call)
-    (method_index_expression
-      method: (identifier) @method.call)
-  ])
+  name:
+    [
+      (identifier) @function.call
+      (dot_index_expression
+        field: (identifier) @function.call)
+      (method_index_expression
+        method: (identifier) @function.method.call)
+    ])
 
 (function_call
   (identifier) @function.builtin
+  ; format-ignore
   (#any-of? @function.builtin
-    ;; built-in functions in Lua 5.1
+    ; built-in functions in Lua 5.1
     "assert" "collectgarbage" "dofile" "error" "getfenv" "getmetatable" "ipairs"
     "load" "loadfile" "loadstring" "module" "next" "pairs" "pcall" "print"
     "rawequal" "rawget" "rawlen" "rawset" "require" "select" "setfenv" "setmetatable"
@@ -227,8 +233,7 @@
     "__idiv" "__index" "__le" "__len" "__lt" "__metatable" "__mod" "__mul" "__name" "__newindex"
     "__pairs" "__pow" "__shl" "__shr" "__sub" "__tostring" "__unm"))
 
-;; Others
-
+; Others
 (comment) @comment @spell
 
 ((comment) @comment.documentation
@@ -237,13 +242,34 @@
 ((comment) @comment.documentation
   (#lua-match? @comment.documentation "^[-][-](%s?)@"))
 
-(hash_bang_line) @preproc
+(hash_bang_line) @keyword.directive
 
 (number) @number
 
-(string) @string @spell
+(string) @string
 
 (escape_sequence) @string.escape
 
-;; Error
-(ERROR) @error
+; string.match("123", "%d+")
+(function_call
+  (dot_index_expression
+    field: (identifier) @_method
+    (#any-of? @_method "find" "match" "gmatch" "gsub"))
+  arguments:
+    (arguments
+      .
+      (_)
+      .
+      (string
+        content: (string_content) @string.regexp)))
+
+;("123"):match("%d+")
+(function_call
+  (method_index_expression
+    method: (identifier) @_method
+    (#any-of? @_method "find" "match" "gmatch" "gsub"))
+  arguments:
+    (arguments
+      .
+      (string
+        content: (string_content) @string.regexp)))
diff --git a/runtime/queries/lua/injections.scm b/runtime/queries/lua/injections.scm
index dbfe75ae31..c8a1843c84 100644
--- a/runtime/queries/lua/injections.scm
+++ b/runtime/queries/lua/injections.scm
@@ -1,35 +1,130 @@
 ((function_call
-  name: [
-    (identifier) @_cdef_identifier
-    (_ _ (identifier) @_cdef_identifier)
-  ]
+  name:
+    [
+      (identifier) @_cdef_identifier
+      (_
+        _
+        (identifier) @_cdef_identifier)
+    ]
   arguments:
     (arguments
-      (string content: _ @injection.content)))
+      (string
+        content: _ @injection.content)))
   (#set! injection.language "c")
   (#eq? @_cdef_identifier "cdef"))
 
 ((function_call
   name: (_) @_vimcmd_identifier
-  arguments: (arguments (string content: _ @injection.content)))
+  arguments:
+    (arguments
+      (string
+        content: _ @injection.content)))
   (#set! injection.language "vim")
   (#any-of? @_vimcmd_identifier "vim.cmd" "vim.api.nvim_command" "vim.api.nvim_command" "vim.api.nvim_exec2"))
 
 ((function_call
   name: (_) @_vimcmd_identifier
-  arguments: (arguments (string content: _ @injection.content) .))
+  arguments:
+    (arguments
+      (string
+        content: _ @injection.content) .))
   (#set! injection.language "query")
   (#any-of? @_vimcmd_identifier "vim.treesitter.query.set" "vim.treesitter.query.parse"))
 
 ((function_call
   name: (_) @_vimcmd_identifier
-  arguments: (arguments . (_) . (string content: _ @_method) . (string content: _ @injection.content)))
+  arguments:
+    (arguments
+      .
+      (_)
+      .
+      (string
+        content: _ @_method)
+      .
+      (string
+        content: _ @injection.content)))
   (#any-of? @_vimcmd_identifier "vim.rpcrequest" "vim.rpcnotify")
   (#eq? @_method "nvim_exec_lua")
   (#set! injection.language "lua"))
 
-;; highlight string as query if starts with `;; query`
-(string content: _ @injection.content
- (#lua-match? @injection.content "^%s*;+%s?query")
- (#set! injection.language "query"))
+; vim.api.nvim_create_autocmd("FileType", { command = "injected here" })
+(function_call
+  name: (_) @_vimcmd_identifier
+  arguments:
+    (arguments
+      .
+      (_)
+      .
+      (table_constructor
+        (field
+          name: (identifier) @_command
+          value:
+            (string
+              content: (_) @injection.content))) .)
+  ; limit so only 2-argument functions gets matched before pred handle
+  (#eq? @_vimcmd_identifier "vim.api.nvim_create_autocmd")
+  (#eq? @_command "command")
+  (#set! injection.language "vim"))
+
+(function_call
+  name: (_) @_user_cmd
+  arguments:
+    (arguments
+      .
+      (_)
+      .
+      (string
+        content: (_) @injection.content)
+      .
+      (_) .)
+  (#eq? @_user_cmd "vim.api.nvim_create_user_command")
+  (#set! injection.language "vim"))
+
+(function_call
+  name: (_) @_user_cmd
+  arguments:
+    (arguments
+      .
+      (_)
+      .
+      (_)
+      .
+      (string
+        content: (_) @injection.content)
+      .
+      (_) .)
+  ; Limiting predicate handling to only functions with 4 arguments
+  (#eq? @_user_cmd "vim.api.nvim_buf_create_user_command")
+  (#set! injection.language "vim"))
 
+; rhs highlighting for vim.keymap.set/vim.api.nvim_set_keymap/vim.api.nvim_buf_set_keymap
+; (function_call
+;   name: (_) @_map
+;   arguments:
+;     (arguments
+;       . (_)
+;       . (_)
+;       .
+;       (string
+;         content: (_) @injection.content))
+;   (#any-of? @_map "vim.api.nvim_set_keymap" "vim.keymap.set")
+;   (#set! injection.language "vim"))
+;
+; (function_call
+;   name: (_) @_map
+;   arguments:
+;     (arguments
+;       . (_)
+;       . (_)
+;       . (_)
+;       .
+;       (string
+;         content: (_) @injection.content)
+;       . (_) .)
+;   (#eq? @_map "vim.api.nvim_buf_set_keymap")
+;   (#set! injection.language "vim"))
+; highlight string as query if starts with `;; query`
+(string
+  content: _ @injection.content
+  (#lua-match? @injection.content "^%s*;+%s?query")
+  (#set! injection.language "query"))